多語言套件使用說明

    TCustomMultiDD是資料字典元件，其下繼承了TAcroMultiFileDD,TAcroMultiDBDD和TAcroMultiStreamDD,TAcroMultiFileDD是從檔獲得字典資料，TAcroMultiDBDD是從資料表獲得字典資料，它們都從外部獲得字典資料，而TAcroMultiStreamDD是從內部獲得字典資料，設計時就輸入了字典資料，編譯到了exe中。屬性DDName:string來識別資料字典。全局元件AcroDDStorage:TAcroMultiDDStorage管理所有的TCustomMultiDD元件，保證它們的DDName唯一。

    全局元件AcroClassMethodStorage:TMultiClassMethodStorage保存註冊的類別的替換函數，按類別的繼承關係，組織成樹形結構。多語言套件預先註冊了Delphi標準元件的替換函數，如TCustomControl，TMenu，TCustomTreeView等。它的功能是為類別找到血緣最近的替換函數。

    TAcroMultiReplacer元件記錄各個元件的替換參數，在Loaded時用元件的類別到AcroClassMethodStorage找它血緣最近的替換函數，自動替換元件的多語言文字。

    套件包含4個Package:

AcroMultiLang60.dpk    運行包，編譯

AcroMultiLang60_Design.dpk    設計包，安裝

AcroMultiDBLang60.dpk    運行包，編譯

AcroMultiDBLang60_Design.dpk    設計包，安裝

如何註冊第三方元件的替換函數?

    多語言套件註冊了下列一些元件:



    如何註冊第三方元件的替換函數呢?很簡單，你只要定義一個下面類型的Procedure，

TMultiLanguageProc=procedure(ATable:IDataLocate;AComponent:TObject;ACodePage,ASeqNo:string;AFont:TFont);

然後調用AcroClassMethodStorage全局元件的RegisterClassMethod註冊即可，如:

　

unit dxClassMethod;
interface
uses
AcroMultiClassMethod;
implementation
uses
Graphics,dxTL,dxTLClms;

procedure Proc_TCustomdxTreeListControl(ATable: IDataLocate; AComponent: TObject;
ACodePage,ASeqNo: string;AFont:TFont);
procedure ReplaceNode(ANode:TdxTreeListNode);
var
    i:integer;
begin
    for i:=0 to TCustomdxTreeListControl(AComponent).ColumnCount-1 do
    if VarIsStr(ANode.Values[i]) then
      ANode.Values[i]:=GetDisplayValue(ATable,ANode.Values[i],ACodePage,ASeqNo);
    for i:=0 to ANode.Count-1 do ReplaceNode(ANode.Items[i]);
end;
var
i,j:integer;
AColumn:TdxTreeListPickColumn;
begin
TCustomdxTreeListControl(AComponent).BeginUpdate;
try
    for i:=0 to TCustomdxTreeListControl(AComponent).Bands.Count-1 do
    begin
      TCustomdxTreeListControl(AComponent).Bands[i].Caption:=
        GetDisplayValue(ATable,TCustomdxTreeListControl(AComponent).Bands[i].Caption,ACodePage,ASeqNo);
    end;
    for i:=0 to TCustomdxTreeListControl(AComponent).ColumnCount-1 do
    begin
      TCustomdxTreeListControl(AComponent).Columns[i].Caption:=
        GetDisplayValue(ATable,TCustomdxTreeListControl(AComponent).Columns[i].Caption,ACodePage,ASeqNo);
      if TCustomdxTreeListControl(AComponent).Columns[i] is TdxTreeListPickColumn then
      begin
        AColumn:=TdxTreeListPickColumn(TCustomdxTreeListControl(AComponent).Columns[i]);
        for j:=0 to AColumn.Items.Count-1 do
          AColumn.Items[j]:=GetDisplayValue(ATable,AColumn.Items[j],ACodePage,ASeqNo);
      end;
    end;
    for i:=0 to TCustomdxTreeListControl(AComponent).Count-1 do
      ReplaceNode(TCustomdxTreeListControl(AComponent).Items[i]);
finally
    TCustomdxTreeListControl(AComponent).EndUpdate;
end;
end;

initialization
AcroClassMethodStorage.RegisterClassMethod(TCustomdxTreeListControl,Proc_TCustomdxTreeListControl);
finalization
AcroClassMethodStorage.UnRegisterClassMethod(TCustomdxTreeListControl);
end.

　

    為何要調用UnRegisterClassMethod來卸載替換函數呢?那是為bpl Plug&Play的系統考慮的。假設系統的主程序沒有用到TCustomdxTreeListControl元件，它不必在主程序引用dxClassMethod單元來註冊TCustomdxTreeListControl元件的替換函數，但系統的一個bpl,如一個訂單的order.bpl,包了一個訂單作業，用到了TCustomdxTreeListControl下面的元件，如TdxTreeList，這個bpl就需要引用dxClassMethod單元；因為order.bpl是主程序載入的(LoadPackage)，用完後，可能主程序會把它卸載(UnLoadPakage),如果這時不卸載此元件的替換函數，再使用Proc_TCustomdxTreeListControl函數時就會訪問到無效位址。

    如果類別是TControl(包含它的後代，下同)，替換函數裏不用替換Hint和Font屬性，內部已經替換了。

如何使用TAcroMultiFileDD?

屬性:

FileName,字典資料來原始檔案,可以使用絕對路徑，如D:\DD\FormDD.abf；也可以使用相對路徑，如果你的exe檔在D:\DD\,那麼FileName可以設為FormDD.abf；如果你的exe檔在D:\，FileName可以設為DD\FormDD.abf

DDReaderID,讀取字典資料的元件類別ID，預設為AcroTextCSV

DDName,字典名稱

FieldsOption,欄位映射

UseDefaultFields,是否使用預設的欄位名稱和數目，預設值True

(1).字典檔的檔格式?

　

    預設的字典資料有5個欄位:

    DDKey    原語

    CodePage    語言識別碼

    SeqNo    多意詞序號

    DisplayValue    原語翻譯詞

    CatalogID    分組識別碼，編輯字典資料時用，實際在替換查詢時沒用

    前3個欄位和為一個Primary Key；

    有三種檔格式:

AcroTextDFM

規則:

第一行為欄位名稱，每個欄位用逗號分隔，值用雙引號包夾；

第二行開始為紀錄資料，每條記錄一行；

雙引號"變成兩個；

ASCII碼小於32的變成#號加上ASCII碼值，且不用雙引號包夾，如回車，變成#13

例:

File "%s" not found!

Retry?

　

輸出結果為:

"File ""%s"" not found!"#13#10"Retry?"

　

字典檔:

"DDKEY","CODEPAGE","SEQNO","DISPLAYVALUE","CATALOGID",
"&Lock","950","0","瑪﹚","100",
"&Lock","936","0","鎖定","100",
"&Lock","1252","0","&Lock","100",
"Log&out","950","0","祅𢴇","100",
"Log&out","936","0","登出","100",
"Log&out","1252","0","Log&out","100",
"&Forms","950","0","跌怠","100",
"&Forms","936","0","視窗","100",
"&Forms","1252","0","&Forms","100",
"&Calculator","950","0","璸衡竟","100",
"&Calculator","936","0","計算器","100",
"&Calculator","1252","0","&Calculator","100",
"&Paint","950","0","婾?產","100",
"&Paint","936","0","小畫家","100",
"&Paint","1252","0","&Paint","100",
"&NotePAD","950","0","癘ㄆ?","100",
"&NotePAD","936","0","記事本","100",
"&NotePAD","1252","0","&NotePAD","100",
"&Help","950","0","臘𦆮","100",
"&Help","936","0","幫助","100",
"&Help","1252","0","&Help","100",
"&About","950","0","閩嬑","100",
"&About","936","0","關於","100",
"&About","1252","0","&About","100",
"Cascade","950","0","糷舼","100",
"Cascade","936","0","層疊","100",
"Cascade","1252","0","Cascade","100",

AcroTextCSV

規則:

第一行為欄位名稱，每個欄位用逗號分隔，值用雙引號包夾；

第二行開始為紀錄資料，每條記錄一行；

雙引號"變成兩個；

回車變成%c

換行變成%n

ASCAII碼0變成%0    -----(注:零)

%變成兩個

例:

File "%s" not found!

Retry?

　

輸出結果為:

"File ""%%s"" not found!%c%nRetry?"

　

字典檔與dfTextDFM類似。

AcroBinary

規則:

連續的位元組流，不分行，具體為:

4位元組，integer    欄位數M

4位元組，integer    第1欄位名稱長度L1

L1位元組，string    第1欄位名稱

4位元組，integer    第2欄位名稱長度L2

L2位元組，string    第2欄位名稱

......

4位元組，integer    第M欄位名稱長度Lm

Lm位元組，string    第M欄位名稱

4位元組，integer    記錄數N

4位元組，integer    第1條記錄第1欄位值長度L1_1

L1_1位元組，string 第1條記錄第1欄位值

4位元組，integer    第1條記錄第2欄位值長度L1_2

L1_2位元組，string 第1條記錄第2欄位值

......

4位元組，integer    第1條記錄第M欄位值長度L1_m

L1_m位元組，string 第1條記錄第M欄位值

......

......

4位元組，integer    第N條記錄第M欄位值長度Ln_m

Ln_m位元組，string 第N條記錄第M欄位值

如果某個欄位值長度為-1,表示Null

(2).為何要用DDName屬性來識別?



    TAcroMultiReplacer為何不直接連接到字典TCustomMultiDD，而要用OwnerOption.ReplaceOption.DDName來間接連接?

    這也是bpl Plug&Play的系統需要的，因為整個系統是分割成了很多的bpl小系統，給不同的程式師來寫；資料字典是整個系統的，可能有一個到幾個，但不可能每個bpl一個，很多的bpl共用一本字典。如果直接連接TcustomMultiDD,要求把系統的字典放到一個公用的bpl,然後每個bpl子系統來引用這個公用的bpl,這就增加了系統的耦合度。(當然，由於公用全局參數的原因，共用bpl是可能存在的)

    而用DDName來間接連接，就不會在這個地方增加系統的耦合度。

    設計時，屬性編輯器列出了所有創建的TCustomMultiDD的DDName，方便為TReplaceOption.DDName挑選，

但不是一定要從列表選取，如果用戶是在子系統，可能設計時TCustomMultiDD還沒有創建(如果TCustomMultiDD是放在資料模組，可能資料模組還沒打開)，屬性編輯器就無法列出，用戶可以直接輸入。

(3).如何獲得每種格式的字典檔?

　

    <1>.先在資料庫建立字典資料表，如FormDD,包含預設的5個欄位:

　

if exists (select * from sysobjects where id = object_id(N'[dbo].[FORMDD]') and OBJECTPROPERTY(id, N'IsUserTable') = 1)
drop table [dbo].[FORMDD]
GO

CREATE TABLE [dbo].[FORMDD] (
[DDKEY] [varchar] (50) NOT NULL ,
[CODEPAGE] [int] NOT NULL ,
[SEQNO] [int] NOT NULL ,
[DISPLAYVALUE] [varchar] (50) NOT NULL ,
[CATALOGID] [varchar] (40) NOT NULL
)
GO

ALTER TABLE [dbo].[FORMDD] WITH NOCHECK ADD
CONSTRAINT [PK_FORMDD] PRIMARY KEY CLUSTERED
(
[DDKEY],
[CODEPAGE],
[SEQNO]
) ON [PRIMARY]
GO

    <2>.用本公司提供的字典編輯工具DDManager編輯資料，然後可以輸出成任一種格式的檔；

    <3>.如果用戶有現成的字典，由於欄位的差異，不能使用DDManager,用戶可以先用TTable,TQuery或TADOTable,TADOQuery等打開字典，調用AcroMultiDBDDWriter.pas的SaveDataSetToXXFile把字典資料輸出到檔。(注意:ASplitor,QuoteChar要用預設值)

procedure SaveDataSetToTextFile(ATable:TDataSet;AFile:string;
EncodeStrFun:TEncodeStrFun;AProc:TProgressProc;const ASplitor:Char=',';
const AQuoteChar:Char='"');

procedure SaveDataSetToBinaryFile(ATable:TDataSet;AFile:string;AProc:TProgressProc);

(4).在何時設定TAcroMultiFileDD的FileName?

　

    在OnBeforeBuildDD事件,此事件是在把字典資料放入Hash表前觸發。

(5).如何過濾進入Hash表的字典資料?

　

    在OnBuildingDD事件，如:

　

procedure TFormMain.AcroMultiFileDD1BuildingDD(Sender: TObject; ADDKey,
ACodePage, ASeqNo: String; var Accept: Boolean);
begin
Accept:=ACodePage='936';
end;

如何使用TAcroMultiStreamDD?

與TAcroMultiFileDD比較，沒有FileName屬性，多了Dictionary:TMultiDictionary屬性，即字典資料不從外部來，而是設計時就建好了資料。適用於不想外帶字典檔的系統，以及內部要使用多語言的bpl，如一些Design Time的Bpl的彈出式編輯器。

用戶可以在設計時用此元件的元件編輯器提供的Load dictionary from file...功能表把字典載入。

如何使用TAcroMultiDBDD?

與TAcroMultiFileDD比較，沒有FileName屬性，多了DataSet:TDataSet屬性，字典資料從TDataSet來，在往Hash表填資料前必須打開。

如何使用TAcroMultiReplacer?

屬性:

OwnerOption:TMultiReplaceOption   TAcroMultiReplacer的Owner的替換參數

ReplaceOption    替換參數

CodePage    要替換成的語言的識別碼

DDName    用哪本字典來替換

SeqNo    多意詞序號

Font    要替換成的字體

ReplaceSelf    是否替換本身，預設True

ReplaceOwned    是否替換它的Components，預設True

ReplaceSon    如果它是TWinControl，是否替換它的Controls，預設True

ReplaceFont    是否替換字體，預設False

ReplaceComs    各個元件的替換參數

UnReplaceComs    不替換的元件

AutoReplace    是否在Loaded時開始替換，預設值為True

(1).既然有了ReplaceComs屬性,為何還要有OwnerOption屬性?

方便性

    省掉用戶每次都要在ReplaceComs裏面加入TAcroMultiReplacer的Owner

必要性

    雖然用戶可以在ReplaceComs裏面加入TAcroMultiReplacer的Owner，如Form1,但是用戶在實際創建TForm1的實例時，實例的名稱不一定都為Form1，如:

var

F1,F2:TForm1;

begin

F1:=TForm1.Create(Application);    //F1的名稱為Form1

F2:=TForm1.Create(Application);    //F2的名稱為Form1_1

end;

因此，TAcroMultiReplacer不能替換F2的多語言。

(2).為何不把ReplaceOption的SeqNo預設值定為0?

　

    SeqNo屬性的類型是string,當在Constructor預設它的值為0後，用戶如果在設計時把它修改成空(他可能不需要一詞多意)，Delphi不會在Form的DFM檔保存SeqNo屬性(屬性保存的條件是:非預設值且Proeprty的定義的Stored值為true。string類型不能在Property定義預設值，它的預設值就是空)。因此當用戶下次打開此Form時，SeqNo的值還是0。

    那為何不把SeqNo屬性的類型設為integer呢?為通用性計，用戶有自己的喜好，張三喜歡把欄位SeqNo定為integer，1,2,3...李四喜歡定為string，A,B,C...如果我們把ReplaceOption.SeqNo設為integer屬性，就不能轉換李四的A,B,C...

如何使用TAcroMultiScreenEye?

    此元件是監視Screen全局元件的OnActiveFormChange事件，在任何Form Active時自動替換它的多語言。由於替換參數使用的是Form的ClassName和元件的Name，因此各個Form不用使用任何的多語言元件，如TAcroMultiReplacer。

屬性:

DefaultReplaceOption    預設的替換參數，當在FormReplaceData裏沒有找到Form的替換參數時，就用此參數

ReplaceData    各種Form類別的替換參數

(1).如何設定某類Form的所有實例共用的參數?

　

    TForm1的實例名稱有Form1,Form1_1,Form1_2...，難道都要一個個加入嗎?

    不必，你把TMultiReplaceDatum.ComName設為Self就行了，如:

    當你對某個實例有不同的替換參數時，可以再加入實例的名稱，如:

　

(2).如何設定某類Form不替換?

　

    在ReplaceData裏加入此Form類別，在TMultiFormReplaceDatum.ReplaceForms裏加入此類別的Self實例，ReplaceOption的ReplaceSelf,ReplaceOwned,ReplaceSon都設為false,ReplaceComs裏面一個元件也沒有。

(3).為何元件不自己在Constructor或Loaded去Hook Screen的OnActiveFormChange事件，而要用戶去調用HookScreenEvent?

　

    為安全計，因為多次Hook事件後，在UnHook時最後可能不能正確恢復事件的原貌，如:

var
Old:TNotifyEvent;
procedure TCom.MyCreate(Sender:TObject);
begin
if Assigned(Old) then Old(Sender);
....Replace Lanaguage....
end;

procedure TCom.Hook;
begin
Old:=Form1.OnCreate;
Form1.OnCreate:=ACreate;
end;

procedure TCom.UnHook;
begin
Form1.OnCreate:=Old;
Old:=nil;
end;

如果A元件Hook了Form1的OnCreate，把Form1原來的事件保存在A.Old,B元件又來Hook了Form1的OnCreate,就把A.MyCreate保存到了B.Old,如果B先UnHook,A再UnHook,沒問題，最後Form1的OnCreate還是它原來的；但如果A先UnHook，B再UnHook呢？最後Form1.OnCreate就是A.MyCreate。
    因此，Hook/UnHook的順序必須按堆疊的方式來進行，先進後出，但Delphi並沒有這樣一個機制來讓大家遵守。因此把Hook的動作留給用戶，用戶可以在Form的Create事件，調用TAcroMultiScreenEye.HookScreenEvent方法開始監視，在Destroy事件，調用TAcroMultiScreenEye.UnHookScreenEvent停止監視。

Demo:

ColorBall遊戲Demo(如何使用TAcroMultiScreenEye) 原碼ColorBall.rar

    這是一個小的物件排列遊戲，相同的物件在一條線上達到一定的數目就會消失，然後增加分值，否則會再多出幾個物件，直到格子塞滿。

    主Form上放了兩個多語言元件，一個AcroMultiStreamDD1:TAcroMultiStreamDD,一個AcroMultiScreenEye1:TAcroMultiScreenEye。

    AcroMultiStreamDD1的DDName為DD0,設計時就把簡繁體兩種語言的資料放在AcroMultiStreamDD1的Dictionary屬性裏了，如果要察看字典內容，可以右鍵單擊此元件，選擇Save Dictionary to File...把字典內容輸出到檔。這樣,就不用外帶字典檔，便於這種小遊戲的分發。

    AcroMultiScreenEye1的DefaultReplaceOption.DDName設為DD0,DefaultReplaceOption.SeqNo設為0，DD0,DefaultReplaceOption.CodePage留到FormCreate裏按作業系統的語言來設；ReplaceNotRegistered設為false,表示不對沒有加到ReplaceData裏的Form替換多語言，如一些訊息方塊，由於是用的API函數MessageBox,它上面的按鈕等本身是作業系統的語言文字，不必替換。ReplaceData裏面加了3項:

FormClassName為TFormColorBall,它的ReplaceForms有一項，FormName為Self；ReplaceOption的DDName也是DD0,SeqNo為0，CodePage也留待FormCreate設；ReplaceComs為空，因為沒有元件要特殊處理；UnReplaceComs裏有一個值:CoolBar_Tool,它是元件名稱，表示它不要替換，因為CollBar的Bands[0].Caption我是用來顯示得分最高者的名字的，不能替換。

FormClassName為TFormOption,它的ReplaceForm也只有Self一項，但其下的UnReplaceComs里加了4個元件名稱:

ComboBox_IconKind    物件種數，為數字，不用替換

ComboBox_LineWidth    滿足銷掉條件的一條線上的連續同類物件數目，為數位，不用替換

ComboBox_NewBallCount    每次新增加的物件數目，為數位，不用替換

ComboBox_Icon    物件的類別，如廚具，昆蟲...它應該替換呀，為何也加入不替換的行列，因為TComboBox元件的關係，我要在參數配置Form的OnShow裏，按現在的參數顯示，如設它的ItemIndex,但當它Activate的時候，它被AcroMultiScreenEye1發現了，於是它的Items都被換成中文，一旦修改Items，ItemIndex自動就設為-1了，那就不能反映現在的參數情況了。(用TAcroMultiReplacer沒有此問題，因為替換比OnShow早)。因此我這裏不能換它，而是在OnShow替換，如:

procedure TFormOption.FormShow(Sender: TObject);
begin
AcroDDStorage.ReplaceComLanguage('DD0',ComboBox_Icon,InttoStr(GetACP),'0',nil,true,false,false,false);
ComboBox_Icon.ItemIndex:=StrToInt(FOption.IconSystem);
ComboBox_LineWidth.ItemIndex:=FOption.LineWidth-2;
ComboBox_IconKind.ItemIndex:=FOption.IconKind-2;
CheckBox_Animate.Checked:=FOption.Animate;
ComboBox_NewBallCount.ItemIndex:=FOption.NewBallCount-1;
CheckBox_PlaySound.Checked:=FOption.PlaySound;
end;

FormClassName為TFormAbout,ReplaceDats加入了Self元件，沒有特殊的處理

    在主Form的OnCreate事件，調用了AcroMultiScreenEye1的HookScreenEvent開始監視Screen的OnActiveFormChange事件，並設了各個ReplaceOption的CodePage,

procedure TFormColorBall.FormCreate(Sender: TObject);
var
i,j,k:integer;
ARD:TMultiReplaceDatum;
ARF:TMultiReplaceForm;
begin
AcroMultiScreenEye1.HookScreenEvent;
AcroMultiScreenEye1.DefaultReplaceOption.CodePage:=InttoStr(GetACP);
for i:=0 to AcroMultiScreenEye1.ReplaceData.Count-1 do
begin
    ARD:=AcroMultiScreenEye1.ReplaceData.Items[i];
    for j:=0 to ARD.ReplaceForms.Count-1 do
    begin
      ARF:=ARD.ReplaceForms.Items[j];
      ARF.ReplaceOption.CodePage:=InttoStr(GetACP);
      for k:=0 to ARF.ReplaceComs.Count-1 do
        ARF.ReplaceComs.Items[k].ReplaceOption.CodePage:=InttoStr(GetACP);
    end;
end;
end;

Delphi VCL元件及第3方元件Demo(如何使用TAcroMultiReplacer) 原碼MultiLangDemo.rar

其中的Demo3rParty.pas是用於第3方元件dev express的，如果用戶沒有，可以從dpr中移出，並移出dxClassMethod.pas

FAQ:

如何得到一個原語的翻譯文字?

(1).AcroMultiDD.pas單元，TCustomMultiDD元件

function GetDisplayValue(ADDKey,ACodePage,ASeqNo:string):string;

(2).AcroMultiDD.pas單元，TAcroMultiDDStorage元件，如全局的AcroDDStorage元件

function GetDisplayValue(ADDName,ADDKey,ACodePage,ASeqNo:string):string;

(3).AcroMultiClassMethod.pas單元的全局function

function GetDisplayValue(ATable:IDataLocate;ADDKey,ACodePage,ASeqNo:string):string;

ATable參數可以傳TCustomMultiDD元件，因為它實作了IDataLocate介面

如何替換一個元件的多語言?

設計時，

(1).可以在TAcroMultiReplacer.ReplaceComs裏加入；

(2).可以在TAcroMultiScreenEye.ReplaceData裏加入；

運行時，

(1).TCustomMultiDD元件

procedure ReplaceComLanguage(ACom:TObject;ACodePage,ASeqNo:string;AFont:TFont;ReplaceSelf,ReplaceOwned,ReplaceSon,ReplaceFont:Boolean);

(2).TAcroMultiDDStorage元件,如全局的AcroDDStorage元件

procedure ReplaceComLanguage(ADDName:string;ACom:TObject;ACodePage,ASeqNo:string;AFont:TFont;ReplaceSelf,ReplaceOwned,ReplaceSon,ReplaceFont:Boolean);

資料字典哪些欄位是必須的，不用CodePage，SeqNo和CatalogID欄位可以嗎?

資料字典的DDKey和DisplayValue欄位是必須的，可以不用CodePage，SeqNo和CatalogID欄位。如果你的欄位名稱或數目不與本公司預設的一致，請把TCustomMultiDD的UseDefaultFields設為False,並在FieldsOption屬性裏指定那4個欄位的名稱，如果欄位名稱為空，表示不使用此欄位。

如何定義自己的資料字典檔格式?

用戶可以從TCustomStreamDDReader元件繼承，來讀取自己的資料流；也可以從TCustomTextStreamDDReader元件繼承，複寫function DecodeStr(const Source:string):string;override;來讀取文本格式的字典資料。

用戶寫好了讀取自己格式資料的元件後，要調用全局元件AcroDDReaderStorage:TAcroMultiStreamDDReaderStorage;的procedure RegisterDDReader(AReaderID:string;AReader:TCustomStreamDDReaderClass);方法來註冊，如在單元的initialization部分:

AcroDDReaderStorage.RegisterDDReader('AcroBinary',TBinaryStreamDDReader);

AReaderID是元件標識，設計時屬性編輯器會為TCustomMultiReaderDD的DDReaderID屬性列出全部註冊了的字典讀取元件的標識字串，如果用戶的元件是在運行時才註冊，屬性編輯器就無法列出，用戶可以直接輸入。

2003.2